Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

LoadVars.getBytesLoaded()

Доступность

Flash Player 6.

Синтаксис

my_lv.getBytesLoaded() : Number

Параметры

Нет.

Возвращает

Число.

Описание

Метод; возвращает число байт, загруженных методом LoadVars.load()или LoadVars.sendAndLoad(). Метод возвращает undefined, если загрузка не производится или еще не началась.

Пример

В следующем примере используется экземпляр компонента ProgressBar и объект LoadVars, загружающий переменные из текстового файла. При тестировании файла на панель Output будет выведено два сообщения: загружен ли файл и сколько байтов загружено. Вы должны заменить параметр URL в методе LoadVars.load()на путь к существующему текстовому файлу, который может быть загружен по протоколу HTTP. Если Вы попробуете использовать файл, находящийся на диске, пример не будет работать корректно, т.к. Flash Player загружает локальные файлы целиком. Добавьте на Сцену компонент ProgressBar и назовите его loadvars_pb:

var loadvars_pb:mx.controls.ProgressBar;
var my_lv:LoadVars = new LoadVars();
loadvars_pb.mode = "manual";
this.createEmptyMovieClip("timer_mc", 999);
timer_mc.onEnterFrame = function() {
  var lvBytesLoaded:Number = my_lv.getBytesLoaded();
  var lvBytesTotal:Number = my_lv.getBytesTotal();
  if (lvBytesTotal != undefined) {
    trace("Loaded "+lvBytesLoaded+" of "+lvBytesTotal+" bytes.");
    loadvars_pb.setProgress(lvBytesLoaded, lvBytesTotal);
  }
};
my_lv.onLoad = function(success:Boolean) {
  loadvars_pb.setProgress(my_lv.getBytesLoaded(), my_lv.getBytesTotal());
  delete timer_mc.onEnterFrame;
  if (success) {
    trace("LoadVars загрузил переменные успешно.");
  } else {
    trace("При загрузке возникла ошибка.");
  }
};
my_lv.load("[поместите сюда путь к существующему файлу, который может быть загружен по Сети]");

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление